AnyEvent::Handle

NAME

AnyEvent::Handle - non-blocking I/O on streaming handles via AnyEvent

SYNOPSIS

   use AnyEvent;
   use AnyEvent::Handle;
   my $cv = AnyEvent->condvar;
   my $hdl; $hdl = new AnyEvent::Handle
      fh => \*STDIN,
      on_error => sub {
         my ($hdl, $fatal, $msg) = @_;
         AE::log error => $msg;
         $hdl->destroy;
         $cv->send;
      };
   # send some request line
   $hdl->push_write ("getinfo\015\012");
   # read the response line
   $hdl->push_read (line => sub {
      my ($hdl, $line) = @_;
      say "got line <$line>";
      $cv->send;
   });
   $cv->recv;

DESCRIPTION

This is a helper module to make it easier to do event-based I/O on stream-based filehandles (sockets, pipes, and other stream things). Specifically, it doesn't work as expected on files, packet-based sockets or similar things. The AnyEvent::Intro tutorial contains some well-documented AnyEvent::Handle examples. In the following, where the documentation refers to "bytes", it means characters. As sysread and syswrite are used for all I/O, their treatment of characters applies to this module as well. At the very minimum, you should specify "fh" or "connect", and the "on_error" callback. All callbacks will be invoked with the handle object as their first argument.

METHODS

$handle = new AnyEvent::Handle fh => $filehandle, key => value...

The constructor supports these arguments (all as "key => value" pairs).

$fh = $handle->fh

This method returns the file handle used to create the AnyEvent::Handle object.

$handle->on_error ($cb)

Replace the current "on_error" callback (see the "on_error" constructor argument).

$handle->on_eof ($cb)

Replace the current "on_eof" callback (see the "on_eof" constructor argument).

$handle->on_timeout ($cb)

$handle->on_rtimeout ($cb)

$handle->on_wtimeout ($cb)

Replace the current "on_timeout", "on_rtimeout" or "on_wtimeout" callback, or disables the callback (but not the timeout) if $cb = "undef". See the "timeout" constructor argument and method.

$handle->autocork ($boolean)

Enables or disables the current autocork behaviour (see "autocork" constructor argument). Changes will only take effect on the next write.

$handle->no_delay ($boolean)

Enables or disables the "no_delay" setting (see constructor argument of the same name for details).

$handle->keepalive ($boolean)

Enables or disables the "keepalive" setting (see constructor argument of the same name for details).

$handle->oobinline ($boolean)

Enables or disables the "oobinline" setting (see constructor argument of the same name for details).

$handle->on_starttls ($cb)

Replace the current "on_starttls" callback (see the "on_starttls" constructor argument).

$handle->on_stoptls ($cb)

Replace the current "on_stoptls" callback (see the "on_stoptls" constructor argument).

$handle->rbuf_max ($max_octets)

Configures the "rbuf_max" setting ("undef" disables it).

$handle->wbuf_max ($max_octets)

Configures the "wbuf_max" setting ("undef" disables it).

$handle->timeout ($seconds)

$handle->rtimeout ($seconds)

$handle->wtimeout ($seconds)

Configures (or disables) the inactivity timeout. The timeout will be checked instantly, so this method might destroy the handle before it returns.

$handle->timeout_reset

$handle->rtimeout_reset

$handle->wtimeout_reset

Reset the activity timeout, as if data was received or sent. These methods are cheap to call.

WRITE QUEUE

AnyEvent::Handle manages two queues per handle, one for writing and one for reading. The write queue is very simple: you can add data to its end, and AnyEvent::Handle will automatically try to get rid of it for you. When data could be written and the write buffer is shorter then the low water mark, the "on_drain" callback will be invoked once.

$handle->on_drain ($cb)

Sets the "on_drain" callback or clears it (see the description of "on_drain" in the constructor). This method may invoke callbacks (and therefore the handle might be destroyed after it returns).

$handle->push_write ($data)

Queues the given scalar to be written. You can push as much data as you want (only limited by the available memory and "wbuf_max"), as "AnyEvent::Handle" buffers it independently of the kernel. This method may invoke callbacks (and therefore the handle might be destroyed after it returns).

$handle->push_write (type => @args)

Instead of formatting your data yourself, you can also let this module do the job by specifying a type and type-specific arguments. You can also specify the (fully qualified) name of a package, in which case AnyEvent tries to load the package and then expects to find the "anyevent_write_type" function inside (see "custom write types", below). Predefined types are (if you have ideas for additional types, feel free to drop by and tell us):

$handle->push_shutdown

Sometimes you know you want to close the socket after writing your data before it was actually written. One way to do that is to replace your "on_drain" handler by a callback that shuts down the socket (and set "low_water_mark" to 0). This method is a shorthand for just that, and replaces the "on_drain" callback with:

   sub { shutdown $_[0]{fh}, 1 }
    

This simply shuts down the write side and signals an EOF condition to the the peer. You can rely on the normal read queue and "on_eof" handling afterwards. This is the cleanest way to close a connection. This method may invoke callbacks (and therefore the handle might be destroyed after it returns).

custom write types - Package::anyevent_write_type $handle, @args

Instead of one of the predefined types, you can also specify the name of a package. AnyEvent will try to load the package and then expects to find a function named "anyevent_write_type" inside. If it isn't found, it progressively tries to load the parent package until it either finds the function (good) or runs out of packages (bad). Whenever the given "type" is used, "push_write" will the function with the handle object and the remaining arguments. The function is supposed to return a single octet string that will be appended to the write buffer, so you can mentally treat this function as a "arguments to on-the-wire-format" converter. Example: implement a custom write type "join" that joins the remaining arguments using the first one.

   $handle->push_write (My::Type => " ", 1,2,3);
   # uses the following package, which can be defined in the "My::Type" or in
   # the "My" modules to be auto-loaded, or just about anywhere when the
   # My::Type::anyevent_write_type is defined before invoking it.
   package My::Type;
   sub anyevent_write_type {
      my ($handle, $delim, @args) = @_;
      join $delim, @args
   }
    

READ QUEUE

AnyEvent::Handle manages two queues per handle, one for writing and one for reading. The read queue is more complex than the write queue. It can be used in two ways, the "simple" way, using only "on_read" and the "complex" way, using a queue. In the simple case, you just install an "on_read" callback and whenever new data arrives, it will be called. You can then remove some data (if enough is there) from the read buffer ("$handle->rbuf"). Or you can leave the data there if you want to accumulate more (e.g. when only a partial message has been received so far), or change the read queue with e.g. "push_read". In the more complex case, you want to queue multiple callbacks. In this case, AnyEvent::Handle will call the first queued callback each time new data arrives (also the first time it is queued) and remove it when it has done its job (see "push_read", below). This way you can, for example, push three line-reads, followed by reading a chunk of data, and AnyEvent::Handle will execute them in order. Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by the specified number of bytes which give an XML datagram.

   # in the default state, expect some header bytes
   $handle->on_read (sub {
      # some data is here, now queue the length-header-read (4 octets)
      shift->unshift_read (chunk => 4, sub {
         # header arrived, decode
         my $len = unpack "N", $_[1];
         # now read the payload
         shift->unshift_read (chunk => $len, sub {
            my $xml = $_[1];
            # handle xml
         });
      });
   });

Example 2: Implement a client for a protocol that replies either with "OK" and another line or "ERROR" for the first request that is sent, and 64 bytes for the second request. Due to the availability of a queue, we can just pipeline sending both requests and manipulate the queue as necessary in the callbacks. When the first callback is called and sees an "OK" response, it will "unshift" another line-read. This line-read will be queued before the 64-byte chunk callback.

   # request one, returns either "OK + extra line" or "ERROR"
   $handle->push_write ("request 1\015\012");
   # we expect "ERROR" or "OK" as response, so push a line read
   $handle->push_read (line => sub {
      # if we got an "OK", we have to _prepend_ another line,
      # so it will be read before the second request reads its 64 bytes
      # which are already in the queue when this callback is called
      # we don't do this in case we got an error
      if ($_[1] eq "OK") {
         $_[0]->unshift_read (line => sub {
            my $response = $_[1];
            ...
         });
      }
   });
   # request two, simply returns 64 octets
   $handle->push_write ("request 2\015\012");
   # simply read 64 bytes, always
   $handle->push_read (chunk => 64, sub {
      my $response = $_[1];
      ...
   });

$handle->on_read ($cb)

This replaces the currently set "on_read" callback, or clears it (when the new callback is "undef"). See the description of "on_read" in the constructor. This method may invoke callbacks (and therefore the handle might be destroyed after it returns).

$handle->rbuf

Returns the read buffer (as a modifiable lvalue). You can also access the read buffer directly as the "->{rbuf}" member, if you want (this is much faster, and no less clean). The only operation allowed on the read buffer (apart from looking at it) is removing data from its beginning. Otherwise modifying or appending to it is not allowed and will lead to hard-to-track-down bugs. NOTE: The read buffer should only be used or modified in the "on_read" callback or when "push_read" or "unshift_read" are used with a single callback (i.e. untyped). Typed "push_read" and "unshift_read" methods will manage the read buffer on their own.

$handle->push_read ($cb)

$handle->unshift_read ($cb)

Append the given callback to the end of the queue ("push_read") or prepend it ("unshift_read"). The callback is called each time some additional read data arrives. It must check whether enough data is in the read buffer already. If not enough data is available, it must return the empty list or a false value, in which case it will be called repeatedly until enough data is available (or an error condition is detected). If enough data was available, then the callback must remove all data it is interested in (which can be none at all) and return a true value. After returning true, it will be removed from the queue. These methods may invoke callbacks (and therefore the handle might be destroyed after it returns).

$handle->push_read (type => @args, $cb)

$handle->unshift_read (type => @args, $cb)

Instead of providing a callback that parses the data itself you can chose between a number of predefined parsing formats, for chunks of data, lines etc. You can also specify the (fully qualified) name of a package, in which case AnyEvent tries to load the package and then expects to find the "anyevent_read_type" function inside (see "custom read types", below). Predefined types are (if you have ideas for additional types, feel free to drop by and tell us):

custom read types - Package::anyevent_read_type $handle, $cb, @args

Instead of one of the predefined types, you can also specify the name of a package. AnyEvent will try to load the package and then expects to find a function named "anyevent_read_type" inside. If it isn't found, it progressively tries to load the parent package until it either finds the function (good) or runs out of packages (bad). Whenever this type is used, "push_read" will invoke the function with the handle object, the original callback and the remaining arguments. The function is supposed to return a callback (usually a closure) that works as a plain read callback (see "->push_read ($cb)"), so you can mentally treat the function as a "configurable read type to read callback" converter. It should invoke the original callback when it is done reading (remember to pass $handle as first argument as all other callbacks do that, although there is no strict requirement on this). For examples, see the source of this module ( perldoc -m AnyEvent::Handle, search for "register_read_type")).

$handle->stop_read

$handle->start_read

In rare cases you actually do not want to read anything from the socket. In this case you can call "stop_read". Neither "on_read" nor any queued callbacks will be executed then. To start reading again, call "start_read". Note that AnyEvent::Handle will automatically "start_read" for you when you change the "on_read" callback or push/unshift a read callback, and it will automatically "stop_read" for you when neither "on_read" is set nor there are any read requests in the queue. In older versions of this module (<= 5.3), these methods had no effect, as TLS does not support half-duplex connections. In current versions they work as expected, as this behaviour is required to avoid certain resource attacks, where the program would be forced to read (and buffer) arbitrary amounts of data before being able to send some data. The drawback is that some readings of the the SSL/TLS specifications basically require this attack to be working, as SSL/TLS implementations might stall sending data during a rehandshake. As a guideline, during the initial handshake, you should not stop reading, and as a client, it might cause problems, depending on your application.

$handle->starttls ($tls[, $tls_ctx])

Instead of starting TLS negotiation immediately when the AnyEvent::Handle object is created, you can also do that at a later time by calling "starttls". See the "tls" constructor argument for general info. Starting TLS is currently an asynchronous operation - when you push some write data and then call "->starttls" then TLS negotiation will start immediately, after which the queued write data is then sent. This might change in future versions, so best make sure you have no outstanding write data when calling this method. The first argument is the same as the "tls" constructor argument (either "connect", "accept" or an existing Net::SSLeay object). The second argument is the optional "AnyEvent::TLS" object that is used when AnyEvent::Handle has to create its own TLS connection object, or a hash reference with "key => value" pairs that will be used to construct a new context. The TLS connection object will end up in "$handle->{tls}", the TLS context in "$handle->{tls_ctx}" after this call and can be used or changed to your liking. Note that the handshake might have already started when this function returns. Due to bugs in OpenSSL, it might or might not be possible to do multiple handshakes on the same stream. It is best to not attempt to use the stream after stopping TLS. This method may invoke callbacks (and therefore the handle might be destroyed after it returns).

$handle->stoptls

Shuts down the SSL connection - this makes a proper EOF handshake by sending a close notify to the other side, but since OpenSSL doesn't support non-blocking shut downs, it is not guaranteed that you can re-use the stream afterwards. This method may invoke callbacks (and therefore the handle might be destroyed after it returns).

$handle->resettls

This rarely-used method simply resets and TLS state on the handle, usually causing data loss. One case where it may be useful is when you want to skip over the data in the stream but you are not interested in interpreting it, so data loss is no concern.

$handle->destroy

Shuts down the handle object as much as possible - this call ensures that no further callbacks will be invoked and as many resources as possible will be freed. Any method you will call on the handle object after destroying it in this way will be silently ignored (and it will return the empty list). Normally, you can just "forget" any references to an AnyEvent::Handle object and it will simply shut down. This works in fatal error and EOF callbacks, as well as code outside. It does NOT work in a read or write callback, so when you want to destroy the AnyEvent::Handle object from within such an callback. You MUST call "->destroy" explicitly in that case. Destroying the handle object in this way has the advantage that callbacks will be removed as well, so if those are the only reference holders (as is common), then one doesn't need to do anything special to break any reference cycles. The handle might still linger in the background and write out remaining data, as specified by the "linger" option, however.

$handle->destroyed

Returns false as long as the handle hasn't been destroyed by a call to "->destroy", true otherwise. Can be useful to decide whether the handle is still valid after some callback possibly destroyed the handle. For example, "->push_write", "->starttls" and other methods can call user callbacks, which in turn can destroy the handle, so work can be avoided by checking sometimes:

   $hdl->starttls ("accept");
   return if $hdl->destroyed;
   $hdl->push_write (...
    

Note that the call to "push_write" will silently be ignored if the handle has been destroyed, so often you can just ignore the possibility of the handle being destroyed.

AnyEvent::Handle::TLS_CTX

This function creates and returns the AnyEvent::TLS object used by default for TLS mode. The context is created by calling AnyEvent::TLS without any arguments.

NONFREQUENTLY ASKED QUESTIONS

I "undef" the AnyEvent::Handle reference inside my callback and still get further invocations!

That's because AnyEvent::Handle keeps a reference to itself when handling read or write callbacks. It is only safe to "forget" the reference inside EOF or error callbacks, from within all other callbacks, you need to explicitly call the "->destroy" method.

Why is my "on_eof" callback never called?

Probably because your "on_error" callback is being called instead: When you have outstanding requests in your read queue, then an EOF is considered an error as you clearly expected some data. To avoid this, make sure you have an empty read queue whenever your handle is supposed to be "idle" (i.e. connection closes are O.K.). You can set an "on_read" handler that simply pushes the first read requests in the queue. See also the next question, which explains this in a bit more detail.

How can I serve requests in a loop?

Most protocols consist of some setup phase (authentication for example) followed by a request handling phase, where the server waits for requests and handles them, in a loop. There are two important variants: The first (traditional, better) variant handles requests until the server gets some QUIT command, causing it to close the connection first (highly desirable for a busy TCP server). A client dropping the connection is an error, which means this variant can detect an unexpected detection close. To handle this case, always make sure you have a non-empty read queue, by pushing the "read request start" handler on it:

   # we assume a request starts with a single line
   my @start_request; @start_request = (line => sub {
      my ($hdl, $line) = @_;
      ... handle request
      # push next request read, possibly from a nested callback
      $hdl->push_read (@start_request);
   });
   # auth done, now go into request handling loop
   # now push the first @start_request
   $hdl->push_read (@start_request);
    

By always having an outstanding "push_read", the handle always expects some data and raises the "EPIPE" error when the connction is dropped unexpectedly. The second variant is a protocol where the client can drop the connection at any time. For TCP, this means that the server machine may run out of sockets easier, and in general, it means you cannot distinguish a protocl failure/client crash from a normal connection close. Nevertheless, these kinds of protocols are common (and sometimes even the best solution to the problem). Having an outstanding read request at all times is possible if you ignore "EPIPE" errors, but this doesn't help with when the client drops the connection during a request, which would still be an error. A better solution is to push the initial request read in an "on_read" callback. This avoids an error, as when the server doesn't expect data (i.e. is idly waiting for the next request, an EOF will not raise an error, but simply result in an "on_eof" callback. It is also a bit slower and simpler:

   # auth done, now go into request handling loop
   $hdl->on_read (sub {
      my ($hdl) = @_;
      # called each time we receive data but the read queue is empty
      # simply start read the request
      $hdl->push_read (line => sub {
         my ($hdl, $line) = @_;
         ... handle request
         # do nothing special when the request has been handled, just
         # let the request queue go empty.
      });
   });
    

I get different callback invocations in TLS mode/Why can't I pause reading?

Unlike, say, TCP, TLS connections do not consist of two independent communication channels, one for each direction. Or put differently, the read and write directions are not independent of each other: you cannot write data unless you are also prepared to read, and vice versa. This means that, in TLS mode, you might get "on_error" or "on_eof" callback invocations when you are not expecting any read data - the reason is that AnyEvent::Handle always reads in TLS mode. During the connection, you have to make sure that you always have a non-empty read-queue, or an "on_read" watcher. At the end of the connection (or when you no longer want to use it) you can call the "destroy" method.

How do I read data until the other side closes the connection?

If you just want to read your data into a perl scalar, the easiest way to achieve this is by setting an "on_read" callback that does nothing, clearing the "on_eof" callback and in the "on_error" callback, the data will be in "$_[0]{rbuf}":

   $handle->on_read (sub { });
   $handle->on_eof (undef);
   $handle->on_error (sub {
      my $data = delete $_[0]{rbuf};
   });
    

Note that this example removes the "rbuf" member from the handle object, which is not normally allowed by the API. It is expressly permitted in this case only, as the handle object needs to be destroyed afterwards. The reason to use "on_error" is that TCP connections, due to latencies and packets loss, might get closed quite violently with an error, when in fact all data has been received. It is usually better to use acknowledgements when transferring data, to make sure the other side hasn't just died and you got the data intact. This is also one reason why so many internet protocols have an explicit QUIT command.

I don't want to destroy the handle too early - how do I wait until all data has been written?

After writing your last bits of data, set the "on_drain" callback and destroy the handle in there - with the default setting of "low_water_mark" this will be called precisely when all data has been written to the socket:

   $handle->push_write (...);
   $handle->on_drain (sub {
      AE::log debug => "All data submitted to the kernel.";
      undef $handle;
   });
    

If you just want to queue some data and then signal EOF to the other side, consider using "->push_shutdown" instead.

I want to contact a TLS/SSL server, I don't care about security.

If your TLS server is a pure TLS server (e.g. HTTPS) that only speaks TLS, connect to it and then create the AnyEvent::Handle with the "tls" parameter:

   tcp_connect $host, $port, sub {
      my ($fh) = @_;
      my $handle = new AnyEvent::Handle
         fh  => $fh,
         tls => "connect",
         on_error => sub { ... };
      $handle->push_write (...);
   };
    

I want to contact a TLS/SSL server, I do care about security.

Then you should additionally enable certificate verification, including peername verification, if the protocol you use supports it (see AnyEvent::TLS, "verify_peername"). E.g. for HTTPS:

   tcp_connect $host, $port, sub {
      my ($fh) = @_;
       my $handle = new AnyEvent::Handle
          fh       => $fh,
          peername => $host,
          tls      => "connect",
          tls_ctx  => { verify => 1, verify_peername => "https" },
          ...
    

Note that you must specify the hostname you connected to (or whatever "peername" the protocol needs) as the "peername" argument, otherwise no peername verification will be done. The above will use the system-dependent default set of trusted CA certificates. If you want to check against a specific CA, add the "ca_file" (or "ca_cert") arguments to "tls_ctx":

       tls_ctx  => {
          verify          => 1,
          verify_peername => "https",
          ca_file         => "my-ca-cert.pem",
       },
    

I want to create a TLS/SSL server, how do I do that?

Well, you first need to get a server certificate and key. You have three options: a) ask a CA (buy one, use cacert.org etc.) b) create a self-signed certificate (cheap. check the search engine of your choice, there are many tutorials on the net) or c) make your own CA (tinyca2 is a nice program for that purpose). Then create a file with your private key (in PEM format, see AnyEvent::TLS), followed by the certificate (also in PEM format). The file should then look like this:

   -----BEGIN RSA PRIVATE KEY-----
   ...header data
   ... lots of base64'y-stuff
   -----END RSA PRIVATE KEY-----
   -----BEGIN CERTIFICATE-----
   ... lots of base64'y-stuff
   -----END CERTIFICATE-----
    

The important bits are the "PRIVATE KEY" and "CERTIFICATE" parts. Then specify this file as "cert_file":

   tcp_server undef, $port, sub {
      my ($fh) = @_;
      my $handle = new AnyEvent::Handle
         fh       => $fh,
         tls      => "accept",
         tls_ctx  => { cert_file => "my-server-keycert.pem" },
         ...
    

When you have intermediate CA certificates that your clients might not know about, just append them to the "cert_file".

SUBCLASSING AnyEvent::Handle

In many cases, you might want to subclass AnyEvent::Handle. To make this easier, a given version of AnyEvent::Handle uses these conventions:

•

all constructor arguments become object members. At least initially, when you pass a "tls"-argument to the constructor it will end up in "$handle->{tls}". Those members might be changed or mutated later on (for example "tls" will hold the TLS connection object).

•

other object member names are prefixed with an "_". All object members not explicitly documented (internal use) are prefixed with an underscore character, so the remaining non-"_"-namespace is free for use for subclasses.

•

all members not documented here and not prefixed with an underscore are free to use in subclasses. Of course, new versions of AnyEvent::Handle may introduce more "public" member variables, but that's just life. At least it is documented.

AUTHOR

Robin Redeker "<elmex at ta-sa.org>", Marc Lehmann <[email protected]>.